猫熊は燃えつきた？！日記

○ tooltip 解決

Meadow で tooltip を出すとすべての frame がフラッシュするだが、お昼休みの地道なチェックで解決した。なぜだかわからないが .emacs に

(custom-set-faces
 ....
 '(border ((t (:foreground "orange3"))))
 ...
 )

があるとおかしくなる。色には依存せず black でも NG となる。

(set-border-color "orange3")
(modify-frame-parameters (selected-frame) '((border-color . "yellow")))

で色を変えても問題ないし、X11 の Emacs は大丈夫なので、なにか Meadow 固有の処理の部分のようだ。また、custom-set-faces() を立ち上り後に実行しても大丈夫みたい。
最初から face を疑っていたので、発見までそんなに時間がかからないで助かったが、記憶をたどるとはるか昔 tooltip がサポートされたころからフラッシュしていたような気がする。border がいつから custom-set-faces() に紛れ込んだかも不明。

○ emacs-w3m で一発タブ移動(改)

以前書いた w3m-goto-buffer だが、w3m-fb-mode => t だとへろへろだったので、書き直してみた。

(setq w3m-add-tab-number t) ;; としておかないと、わけがわからんぞ
  
(add-hook 'w3m-mode-hook
	  (lambda ()
	    (let ((key1 ?\C-0)
		  (key2 ?\M-0)
		  (ch 0))
	      (while (< ch 10)
		(define-key w3m-mode-map (vector (+ key1 ch)) 'w3m-goto-buffer)
		(define-key w3m-mode-map (vector (+ key2 ch)) 'w3m-goto-buffer)
		(setq ch (1+ ch))))))
  
(defun w3m-goto-buffer (&optional arg)
  "Goto w3m buffer to accompany inputed numbers like the following,
C-2 => *w3m*<2>
M-0 => *w3m*<max>
12M-3 => *w3m*<123>"
  (interactive "p")
  (let* ((num (+ (- (logand last-command-char ?\177) ?0)
		 (if (not current-prefix-arg)
		     0
		   (* arg 10))))
	 (bufs (w3m-list-buffers))
	 (max (length bufs))
	 (buf (if (or (= num 0) (> num max))
		  (nth (1- max) bufs)
		(nth (1- num) bufs)))
	 (bufname (when (and buf (buffer-live-p buf))
		    (buffer-name buf)))
	 win)
    (if (not bufname)
	(message "No exist w3m buffer")
      (cond
       ((eq major-mode 'w3m-mode)
	(set-window-buffer (selected-window) buf))
       ((setq win (catch 'win
		    (walk-windows
		     (lambda (w)
		       (save-excursion
			 (set-buffer (window-buffer w))
			 (when (eq major-mode 'w3m-mode)
			   (throw 'win w)))))))
	(select-window win)
	(set-window-buffer win buf))
       (t
	(pop-to-buffer buf)))
      (w3m-select-buffer-update)
      (message "Goto w3m buffer \"%s\"" bufname))))

○ 伊藤さんの Lookup の ndebsエージェント

って、なかなか良いでしょ :-)

ぼくは、とっても気に入りました。そうすると SDIC で array がたくさん立ち上がっているのがとても気になるのだけど。