猫熊は燃えつきた？！日記

○ 日記

も久しぶりだなぁ〜〜。

○ 出張

先週から今週頭にかけては、途中ちょっと除いて、宇都宮の工場に出張していた。

先週は、木曜日の夜に一度帰る予定だったのだけど、台風来ちゃったから工場を 14:30 に出て自宅に 17:00 に到着。次の日は目黒に出社だったのだけど、午前中半休！にしてしまったので、台風のときには一回も傘をさしていないし、めちゃ混みの電車にも乗らずにすんでしまった。 :-)

今週もずーーとの予定だったのだけど、ノルマが終わったので、火曜日でお終い。

○ 以下、

最近やったことのまとめ。基本的に忙しいのと、いまだにモヤモヤしているので大したことはしていない。

○ lookup で Wikipedia

伊藤さんの wikipedia-fpw を使って、epwing 化した Wikipedia を作ってみた。ebzip -l 5 をかけて

% du -k WIKIP/
599217	WIKIP/WIKIP/data
1	WIKIP/WIKIP/gaiji
599219	WIKIP/WIKIP
599243	WIKIP

な感じ。なにか他のものを消せば Zaurus にも入るんだけどなぁ。。。どーしよー。

○ elscreen-server

森島さんの elscreen-server だけど、Emacs CVS Head が multi-tty をサポートして Emacs 23.0.50 になってからエラーするようになった。
ちょっと手抜きのような気もするのだけどパッチ。

--- elscreen-server.el.old	2006-07-25 18:15:36.000000000 +0900
+++ elscreen-server.el	2007-08-31 13:33:05.000000000 +0900
@@ -42,7 +42,8 @@
  ((fboundp 'server-visit-files)
   ;; For server.el distributed with GNU Emacs
   (defadvice server-visit-files (after elscreen-server-visit-files activate)
-    (elscreen-server-visit-files-new-screen (cdr ad-return-value))))
+    (elscreen-server-visit-files-new-screen (or (cdr ad-return-value)
+						ad-return-value))))
  ((fboundp 'gnuserv-edit-files)
   ;; For (current) gnuserv typically used with XEmacs
   (defadvice gnuserv-edit-files (around elscreen-gnuserv-edit-files activate)

ちと忙しくて報告が遅れたが、森島さんが elscreen の話をする ML には報告しておいた。

○ Mew でメッセージの横スクロール

一回 Mew-dist に出したものの焼き直しだが、summary での <, > が横スクロールになるのは、message buffer が truncate-lines => t のときだけにして、それ以外の場合は、従来の mew-summary-jump-top|bottom が動く。

(defcustom mew-message-horizontal-scroll-columns 15
  "*Number of steps in columns used when scrolling a message window horizontally."
  :group 'mew-message
  :type '(integer :size 0))
 
(add-hook 'mew-summary-mode-hook
	  (lambda ()
	    (define-key mew-summary-mode-map "<" 'mew-summary-jump-top-or-scroll-right)
	    (define-key mew-summary-mode-map ">" 'mew-summary-jump-bottom-or-scroll-left)))
 
(add-hook 'mew-message-mode-hook
	  (lambda ()
	    (define-key mew-message-mode-map "<" 'mew-message-scroll-right)
	    (define-key mew-message-mode-map ">" 'mew-message-scroll-left)))
 
(cond
 ((boundp 'auto-hscroll-mode) ;; Emacs 21.3.50 or later
  (defsubst mew-hscroll-off ()
    (set (make-local-variable 'auto-hscroll-mode) nil))
  (defsubst mew-hscroll-type ()
    (if auto-hscroll-mode 'on 'off)))
 ((boundp 'automatic-hscrolling) ;; Emacs 21.3 or earlier
  (defsubst mew-hscroll-off ()
    (set (make-local-variable 'automatic-hscrolling) nil))
  (defsubst mew-hscroll-type ()
    (if automatic-hscrolling 'on 'off)))
 (t
  (defsubst mew-hscroll-off () (auto-show-mode 0))
  (defsubst mew-hscroll-type ()
    (if auto-show-mode 'on 'off))))
 
(defvar mew-hscroll-type nil)
(make-variable-buffer-local 'mew-hscroll-type)
 
(defadvice mew-normal-line (before hscroll-off activate)
  (when (eq mew-hscroll-type 'on)
    (mew-hscroll))
  (let ((fld (mew-minfo-get-summary)))
    (when (and fld (get-buffer fld))
      (save-excursion
	(set-buffer fld)
	(when (eq mew-hscroll-type 'on)
	  (mew-hscroll))))))
 
(defun mew-summary-jump-bottom-or-scroll-left (arg)
  "Scroll the message window to the left."
  (interactive "P")
  (unless (and (mew-buffer-message)
	       (get-buffer-window (mew-buffer-message))
	       (mew-summary-msg-or-part
		(unless mew-hscroll-type
		  (setq mew-hscroll-type (mew-hscroll-type)))
		(mew-hscroll-off)
		(let ((win (selected-window))
		      ret)
		  (unwind-protect
		      (progn
			(mew-summary-toggle-disp-msg 'on)
			(if (memq last-command '(mew-summary-jump-bottom-or-scroll-left
						 mew-summary-jump-top-or-scroll-right))
			    (when (get-buffer-window (mew-buffer-message))
			      (select-window (get-buffer-window (mew-buffer-message))))
			  (mew-window-configure 'message))
			(setq ret (mew-message-scroll-left arg)))
		    (select-window win)
		    ret))))
    (call-interactively 'mew-summary-jump-bottom)))
 
(defun mew-summary-jump-top-or-scroll-right (arg)
  "Scroll the message window to the right."
  (interactive "P")
  (unless (and (mew-buffer-message)
	       (get-buffer-window (mew-buffer-message))
	       (mew-summary-msg-or-part
		(unless mew-hscroll-type
		  (setq mew-hscroll-type (mew-hscroll-type)))
		(mew-hscroll-off)
		(let ((win (selected-window))
		      ret)
		  (unwind-protect
		      (progn
			(mew-summary-toggle-disp-msg 'on)
			(if (memq last-command '(mew-summary-jump-bottom-or-scroll-left
						 mew-summary-jump-top-or-scroll-right))
			    (when (get-buffer-window (mew-buffer-message))
			      (select-window (get-buffer-window (mew-buffer-message))))
			  (mew-window-configure 'message))
			(setq ret (mew-message-scroll-right arg)))
		    (select-window win)
		    ret))))
    (call-interactively 'mew-summary-jump-top)))
 
(defun mew-message-scroll-left (arg)
  "Scroll the message window to the left."
  (interactive "P")
  (mew-message-horizontal-scroll
   'left (if arg
	     (prefix-numeric-value arg)
	   mew-message-horizontal-scroll-columns)))
 
(defun mew-message-scroll-right (arg)
  "Scroll the message window to the right."
  (interactive "P")
  (mew-message-horizontal-scroll
   'right (if arg
	      (prefix-numeric-value arg)
	    mew-message-horizontal-scroll-columns)))
 
(defun mew-message-horizontal-scroll (direction ncol)
  "Scroll the message window NCOL columns horizontally to DIRECTION.
DIRECTON should be the symbol `left' which specifies to scroll to the
left, or any other Lisp object meaning to scroll to the right.  NCOL
should be a number. "
  (when truncate-lines
    (let ((inhibit-point-motion-hooks t))
      (unless mew-hscroll-type
	(setq mew-hscroll-type (mew-hscroll-type)))
      (mew-hscroll-off)
      (set-window-hscroll (selected-window)
			  (max 0 (+ (window-hscroll)
				    (if (eq direction 'left) ncol (- ncol)))))
      (let ((hs (window-hscroll)))
	(unless (and (>= (- (current-column) hs) 0)
		     (< (- (current-column) hs) (window-width)))
	  (move-to-column (if (eq direction 'left)
			      hs
			    (+ hs (window-width) -2))))
	hs))))